build.gradle

plugins {
    id 'base'
    // see https://fabricmc.net/develop/ for new versions
    id "net.fabricmc.fabric-loom" version '1.17-SNAPSHOT' apply false
    // see https://projects.neoforged.net/neoforged/moddevgradle for new versions
    id 'net.neoforged.moddev' version '2.0.141' apply false
}

apply plugin: 'idea'
idea {
    module {
        downloadSources = true
    }
}


tasks.register('collectJars', Copy) {
    def fabricJars = file("fabric/build/libs")
    if (fabricJars.exists()) {
        from(fabricJars) {
            include '*.jar'
            exclude '*-sources.jar', '*-javadoc.jar', '*-dev-shadow.jar'
        }
    }

    def neoJars = file("neoforge_coremod/build/libs")
    if (neoJars.exists()) {
        from(neoJars) {
            include '*.jar'
            exclude '*-sources.jar', '*-javadoc.jar', '*-dev-shadow.jar'
            rename { originalName ->
                originalName.replace("_coremod", "")
            }
        }
    }

    into("$rootDir/build/libs")
}

build.finalizedBy(collectJars)